Membuat Menu Sendiri di Access

Dengan menggunakan tools yang dimiliki Access, kita bisa membuat menu sendiri. Perangkat yang digunakan untuk membuat menu pada Access itu bernama Switchboard Manager. Dengan Switchboard Manager, kita bisa mengatur tampilan form, report, modul, macro yang akan dieksekusi. Pada bagian ini, kita tidak akan membahas menu yang dibuat melalui switchboard manager. Kita akan membuat menu sendiri yang proses eksekusinya disesuaikan dengan hak akses dari pengguna.
Menu yang digunakan untuk menampilkan form ini dibuat melalui dua tahap. Tahap pertama, melakukan pengaturan menu. Pengaturan ini dilakukan dengan membuat form untuk mengatur menu apa saja yang akan ditampilkan, ijin yang dipersyaratkan, dan urutannya, seperti dijelaskan pada posting yang berjudul Membuat Form untuk Mengatur Menu di Access. Yang kedua, membuat menu itu sendiri. Menu ini akan ditampilkan sesuai dengan parameter yang diatur melalui form Pengaturan Menu dan Administrasi Pengguna.

Gambar 1

Cara Membuat Menu Sendiri

Menu adalah bagian penting dari sebuah sistem karena dari sinilah, pengguna bisa melihat hal apa saja yang bisa dilakukan. Bentuk menu yang akan kita buat sangatlah sederhana, hanya berisi pilihan-pilihan yang dibuat melalui kombinasi text box yang diletakkan di atas tombol perintah seperti tampak pada Gambar 1. Record source form ini menggunakan query:

SELECT NamaForm,NoUrut,Induk, StatusPermisi([NamaIjin]) AS Status,Id FROM tblMenus WHERE Induk=0 AND StatusPermisi( [NamaIjin])="y" ORDER BY NoUrut;

Untuk membuatnya, ikuti langkah berikut ini.

1. Buatlah menu menggunakan Blank Form. Simpanlah form dengan nama frmMenus. Adapun proerti form ini adalah sebagai berikut:
   
   1. Allow Additions=No
   2. Allow Edits=No
   3. Allow Deletion=No
   4. Auto Resize=Yes
   5. Record Selectors=No
   6. Record Navigations=No
   7. Close Button=No
   8. Min Max Buttons=None
2. Sisipkanlah text box yang berfungsi sebagai judul menu di bagian header. Pada properti Control Source dari text box ini, isikan formula:
   ="Menu " & nz(DLookUp("[NamaForm]","[tblMenus]"," [Id] =" & [intInduk]),"Utama")
3. Pada bagian detail, sisipkan text box dari field Id, properti:
   
   1. Name=Id
   2. Control Source=Id
   3. Visible=No
4. Masih di bagian detail, sisipkan tombol perintah kosong dengan properti dibiarkan apa adanya. Di atas tombol perintah ini, sisipkan text box dengan properti:
   
   1. Name=NamaForm
   2. Control Source=NamaForm
   3. Is Hyperlink=Yes
5. Pada bagian footer, sisipkan tombol perintah untuk keluar dari Access, properti:
   
   1. Name=Keluar
   2. Caption=Keluar
6. Di sebelah kanan tombol perintah Keluar, sisipkan tombol perintah untuk menutup aplikasi database, properti:
   
   1. Name=Tutup
   2. Caption= Tutup
7. Di sebelah kanan tombol perintah Tutup, sisipkan text box dari field Induk, properti:
   
   1. Name=Induk
   2. Control Source=Induk
   3. Visible=No
8. Di samping text box Induk, sisipkan tombol perintah untuk kembali ke menu sebelumnya (bila ada), dengan properti:
   
   1. Name=Kembali
   2. Caption= Kembali

Kode VBA untuk modul form frmMenus ini adalah sebagai berikut:

Option Compare Database
Private Sub Form_Current()
  If Me.Induk = 0 Then Me.Kembali.Visible = False Else Me.Kembali.Visible = True
End Sub
Private Sub Form_Open(Cancel As Integer)
  Me.Caption = "Menu Utama " & Nz(IdPerusahaan("Nama"), "")
  If Not IsNull(Me.LoginPgn) Then Me.logout.Visible = True
End Sub
Private Sub Kembali_Click()
  Dim intId As Integer
  intId = DLookup("[Induk]", "tblMenus", "[Id]=" & Me.Induk)
  Me.RecordSource = "SELECT NamaForm, NoUrut, Id, Induk FROM tblMenus WHERE Induk= " & intId & " and StatusPermisi([NamaIjin])='y' ORDER BY NoUrut;"
  Me.Requery
End Sub
Private Sub NamaForm_Click()
  Dim strIdForm As String
  If IsNull(DLookup("[IdForm]", "tblMenus", "[Id]=" & Me.Id)) Then
    Me.RecordSource = "SELECT NamaForm, NoUrut, Id, NamaIjin, StatusPermisi([NamaIjin]) AS Status, Induk FROM tblMenus WHERE Induk= " & Me.Id & " and StatusPermisi([NamaIjin])='y' ORDER BY NoUrut;"
    Me.Requery
    Exit Sub
  Else
    Form.Visible = False
    BukaForm (DLookup("[IdForm]", "tblMenus", "[Id]=" & Me.Id))
  End If
End Sub
Private Sub Keluar_Click()
  KeluarDariAccss
End Sub
Private Sub Tutup_Click()
  TutupAplikasiIni
End Sub

Gambar 2

Bila form itu dijalankan, maka tampilan dalam bentuk Form view akan seperti Gambar 2 di atas. Menu Rekening pada gambar itu merupakan tampilan submenu yang diatur sesuai dengan tabel di posting yang berjudul Membuat Form untuk Mengatur Menu di Access.