Membuat Sendiri FIle Dialog Menggunakan VBA di MS Access

Kita bisa membuat sendiri sebuah FIle Dialog dengan menggunakan VBA di MS Access. File Dialog atau dialog file adalah sebuah kotak yang menampilkan daftar direktori, folder, atau file. Dengan menggunakan daftar ini, pengguna komputer dipersilakan untuk memilih rincian yang ada di dalamnya.


Kita bisa menggunakan file dialog untuk menautkan sebuah folder, memilih beberapa macam file dan menyimpan file. Sebagai contoh, untuk memilih satu atau lebih file Excel, kita bisa menekan menu File, lalau pilih Open. Sebuah kotak file dialog akan terbuka dan kita bisa menyeleksi berbagai macam file Excel yang akan dipilih. Demikian pula saat kita memilih menu File, lalu pilih Save As, maka sebuah kotak file dialog akan terbuka dan kita bisa memilih atau mengetikkan nama file yang baru untuk disimpan.

Gambar 1. Kotak File Dialog untuk memilih folder

Untuk membuat kotak file dialog di VBA, kita menggunakan objek Application.FileDialog. Cara penulisannya adalah sebagai berikut:

Application.FileDialog(tipeFileDialog)

Parameter tipeFileDialog adalah sebuah pilihan dalam daftar msoFileDialogType yang terdiri dari:

Nilai	Keterangan
msoFileDialogOpen	Kotak dialog untuk membuka file
msoFileDialogSaveAs	Kota dialog untuk menyimpan sebuah file
msoFileDialogFilePicker	Kotak dialog untuk memilih file
msoFileDialogFolderPicker	Kotak dialog untuk memilih folder

Adapun properti dari FileDiaolog adalah sebagai berikut:

Properti	Keterangan
AllowMultiSelect	Mengarahkan file dialog unuk memilih satu atau lebih file atau folder. Nilai berupa boolean True atau False.
ButtonName	Teks yang ditampilkan pada tombol perintah di kotak dialog.
DialogType	Mengubah MsoFileDialogType (lihat tabel di atas)
Filter	Mengatur filter untuk memilih jenis file yang ingin ditampilkan, misalnya: file yang berekstensi *.docx,  *.doc, *.mdb, *.txt, dan sebagainya.
InitialFileName	Nama path saat kotak fIle dialog terbuka. misalnya: C:\
InitialView	Bentuk tampilan saat kotak dialog terbuka, nilainya sebagai berikut: Nilai msoFileDialogViewDetails msoFileDialogViewLargeIcons msoFileDialogViewList msoFileDialogViewPreview msoFileDialogViewProperties msoFileDialogViewSmallIcons msoFileDialogViewThumbnail msoFileDialogViewWebView
SelectedItems	Collection of type FileDialogSelectedItems with all selected items
Title	Judul dari kotak file dialog.
Show	Mengarahkan file dialog untuk menampilkan atau membatalkan hasil seleksi file atau folder di kotak file dialog. Nilai berupa boolean True atau False.

Keterkaitan properti dengan kotak dialog dapat dijelaskan pada gambar di bawah ini. Kode yang digunakan dapat dilihat pada contoh di bawah (Contoh File Dialog untuk memilih file image/gambar).

Gambar 2. Kotak File Dialog untuk memilih file beserta keterkaitan dengan properti FileDialog

Contoh File Dialog untuk memilih file image/gambar

Berikut ini adalah kode VBA yang digunakan untuk memilih file gambar:

view plainprint?

1. Function kotakFileDialog (Optional strFileName As String = "", Optional boolAllowMultiSelect As Boolean = False) As String  
2. 'Aktifkan Microsoft Office Object Library pada Tools - References... (minimum 12.0).  
3.   Dim fd As Office.FileDialog  
4.   Dim vrtSelectedItem As Variant, itemFile() As String, i As Integer  
5.     
6.   Set fd = Application.FileDialog(msoFileDialogFilePicker)  
7.     
8.   With fd  
9.     .AllowMultiSelect = boolAllowMultiSelect  
10.     .InitialView = msoFileDialogViewList  
11.     .Title = "Pilih File Gambar"  
12.     .Filters.Clear  
13.     .Filters.Add "Images", "*.gif; *.jpg; *.jpeg; *.png; *.bmp", 1  
14.     .ButtonName = "Tes pilih file"  
15.     If .Show Then  
16.       If .AllowMultiSelect Then  
17.         ReDim Preserve itemFile(.SelectedItems.Count - 1)  
18.         i = 0  
19.         For Each vrtSelectedItem In .SelectedItems  
20.           itemFile(i) = vrtSelectedItem  
21.           i = i + 1  
22.         Next vrtSelectedItem  
23.         kotakFileDialog = Join(itemFile, ",")  
24.       Else  
25.         kotakFileDialog = .SelectedItems.Item(1)  
26.       End If  
27.     Else  
28.       If strFileName <> "" Then kotakFileDialog = strFileName  
29.     End If  
30.   End With  
31.       
32.   Set fd = Nothing  
33.   
34. End Function  

Function kotakFileDialog (Optional strFileName As String = "", Optional boolAllowMultiSelect As Boolean = False) As String
'Aktifkan Microsoft Office Object Library pada Tools - References... (minimum 12.0).
  Dim fd As Office.FileDialog
  Dim vrtSelectedItem As Variant, itemFile() As String, i As Integer
  
  Set fd = Application.FileDialog(msoFileDialogFilePicker)
  
  With fd
    .AllowMultiSelect = boolAllowMultiSelect
    .InitialView = msoFileDialogViewList
    .Title = "Pilih File Gambar"
    .Filters.Clear
    .Filters.Add "Images", "*.gif; *.jpg; *.jpeg; *.png; *.bmp", 1
    .ButtonName = "Tes pilih file"
    If .Show Then
      If .AllowMultiSelect Then
        ReDim Preserve itemFile(.SelectedItems.Count - 1)
        i = 0
        For Each vrtSelectedItem In .SelectedItems
          itemFile(i) = vrtSelectedItem
          i = i + 1
        Next vrtSelectedItem
        kotakFileDialog = Join(itemFile, ",")
      Else
        kotakFileDialog = .SelectedItems.Item(1)
      End If
    Else
      If strFileName <> "" Then kotakFileDialog = strFileName
    End If
  End With
    
  Set fd = Nothing

End Function

Contoh eksekusi file di Immediate Window dengan mengaktifkan multiple file (AllowMultiSelect):

view plainprint?

1. ?kotakFileDialog(,True)  
2. C:\Documents and Settings\User1\My Documents\My Pictures\DSCN3887.JPG,C:\Documents and Settings\User1\My Documents\My Pictures\DSCN3869.JPG,C:\Documents and Settings\User1\My Documents\My Pictures\DSCN3874.JPG,C:\Documents and Settings\User1\My Documents\My Pictures\DSCN3883.JPG  

?kotakFileDialog(,True)
C:\Documents and Settings\User1\My Documents\My Pictures\DSCN3887.JPG,C:\Documents and Settings\User1\My Documents\My Pictures\DSCN3869.JPG,C:\Documents and Settings\User1\My Documents\My Pictures\DSCN3874.JPG,C:\Documents and Settings\User1\My Documents\My Pictures\DSCN3883.JPG

Contoh File Dialog untuk memilih folder

Berikut ini adalah kode VBA yang digunakan untuk memilih folder:

view plainprint?

1. Function membukaFolder(Optional strFileName As String = "") As String  
2.     Dim lngCount As Long  
3.  'Aktifkan Microsoft Office Object Library pada Tools - References... (minimum 12.0).  
4.     With Application.FileDialog(msoFileDialogFolderPicker)  
5.       .Filters.Clear  
6.       .Title = "Membuka folder"  
7.       If .Show Then  
8.         membukaFolder = Trim(.SelectedItems.Item(1))  
9.       Else  
10.         If strFileName <> "" Then membukaFolder = strFileName  
11.       End If  
12.     End With  
13. End Function  

Function membukaFolder(Optional strFileName As String = "") As String
    Dim lngCount As Long
 'Aktifkan Microsoft Office Object Library pada Tools - References... (minimum 12.0).
    With Application.FileDialog(msoFileDialogFolderPicker)
      .Filters.Clear
      .Title = "Membuka folder"
      If .Show Then
        membukaFolder = Trim(.SelectedItems.Item(1))
      Else
        If strFileName <> "" Then membukaFolder = strFileName
      End If
    End With
End Function

Memfilter file dialog

Pengaturan untuk memilih dua file atau lebih dengan menggunakan Application.FileDialog mungkin bisa menimbulkan masalah. Masalah akan timbul bila hasil/output dari Application.FileDialog berisi nama-nama file yang sudah dipilih melalui eksekusi perintah Application.FileDialog sebelumnya. Untuk mencegah masalah seperti ini, maka kita harus mengikutsertakan metode .Filters.Clear sebelum semua pilihan file ditampilkan sebagai output.